uv: init module

modules/modules.nix

@@ -277,6 +277,7 @@ let
       ./programs/topgrade.nix
       ./programs/translate-shell.nix
       ./programs/urxvt.nix
+      ./programs/uv.nix
       ./programs/vdirsyncer.nix
       ./programs/vesktop.nix
       ./programs/vifm.nix

modules/programs/uv.nix

@@ -0,0 +1,56 @@
+{
+  pkgs,
+  config,
+  lib,
+  ...
+}:
+
+let
+
+  inherit (lib)
+    mkEnableOption
+    mkPackageOption
+    mkOption
+    literalExpression
+    ;
+
+  tomlFormat = pkgs.formats.toml { };
+  cfg = config.programs.uv;
+
+in
+{
+  meta.maintainers = with lib.maintainers; [ mirkolenz ];
+
+  options.programs.uv = {
+    enable = mkEnableOption "uv";
+
+    package = mkPackageOption pkgs "uv" { };
+
+    settings = mkOption {
+      type = tomlFormat.type;
+      default = { };
+      example = literalExpression ''
+        {
+          python-downloads = "never";
+          python-preference = "only-system";
+          pip.index-url = "https://test.pypi.org/simple";
+        }
+      '';
+      description = ''
+        Configuration written to
+        {file}`$XDG_CONFIG_HOME/uv/uv.toml`.
+        See <https://docs.astral.sh/uv/configuration/files/>
+        and <https://docs.astral.sh/uv/reference/settings/>
+        for more information.
+      '';
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    home.packages = [ cfg.package ];
+
+    xdg.configFile."uv/uv.toml" = lib.mkIf (cfg.settings != { }) {
+      source = tomlFormat.generate "uv-config" cfg.settings;
+    };
+  };
+}

tests/default.nix

@@ -466,6 +466,7 @@ import nmtSrc {
       ./modules/programs/tmux
       ./modules/programs/topgrade
       ./modules/programs/translate-shell
+      ./modules/programs/uv
       ./modules/programs/vifm
       ./modules/programs/vim-vint
       ./modules/programs/vscode

tests/modules/programs/uv/default.nix

@@ -0,0 +1,4 @@
+{
+  uv-example-settings = ./example-settings.nix;
+  uv-no-settings = ./no-settings.nix;
+}

tests/modules/programs/uv/example-settings.nix

@@ -0,0 +1,29 @@
+{ pkgs, ... }:
+
+{
+  programs.uv = {
+    enable = true;
+    settings = {
+      python-downloads = "never";
+      python-preference = "only-system";
+      pip.index-url = "https://test.pypi.org/simple";
+    };
+  };
+
+  test.stubs.uv = { };
+
+  nmt.script =
+    let
+      expectedConfigPath = "home-files/.config/uv/uv.toml";
+      expectedConfigContent = pkgs.writeText "uv.config-custom.expected" ''
+        python-downloads = "never"
+        python-preference = "only-system"
+        [pip]
+        index-url = "https://test.pypi.org/simple"
+      '';
+    in
+    ''
+      assertFileExists "${expectedConfigPath}"
+      assertFileContent "${expectedConfigPath}" "${expectedConfigContent}"
+    '';
+}

tests/modules/programs/uv/no-settings.nix

@@ -0,0 +1,16 @@
+{ ... }:
+{
+  programs.uv = {
+    enable = true;
+  };
+
+  test.stubs.uv = { };
+
+  nmt.script =
+    let
+      expectedConfigPath = "home-files/.config/uv/uv.toml";
+    in
+    ''
+      assertPathNotExists "${expectedConfigPath}"
+    '';
+}