anup: add module

modules/programs/anup.nix

@@ -0,0 +1,39 @@
+{
+  lib,
+  pkgs,
+  config,
+  ...
+}:
+let
+  inherit (lib)
+    types
+    mkIf
+    mkEnableOption
+    mkPackageOption
+    mkOption
+    ;
+
+  cfg = config.programs.anup;
+in
+{
+  meta.maintainers = with lib.hm.maintainers; [ aguirre-matteo ];
+  options.programs.anup = {
+    enable = mkEnableOption "anup";
+    package = mkPackageOption pkgs "anup" { nullable = true; };
+    config = mkOption {
+      type = with types; either str path;
+      default = "";
+      description = ''
+        Config file for anup in RON (Rusty Object Notation) format.
+        Available options can be found by looking at ~/.config/anup/config.ron.
+      '';
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = mkIf (cfg.package != null) [ cfg.package ];
+    home.file.".config/anup/config.ron" = mkIf (cfg.config != "") {
+      source = if lib.isPath cfg.config then cfg.config else pkgs.writeText "anup-config.ron" cfg.config;
+    };
+  };
+}

tests/modules/programs/anup/config.ron

@@ -0,0 +1,14 @@
+(
+    series_dir: "/home/matteo/anime",
+    reset_dates_on_rewatch: false,
+    episode: (
+        percent_watched_to_progress: (50.0),
+        player: "mpv",
+        player_args: [],
+    ),
+    tui: (
+        keys: (
+            play_next_episode: "enter",
+        ),
+    ),
+)

tests/modules/programs/anup/default.nix

@@ -0,0 +1 @@
+{ anup-settings = ./settings.nix; }

tests/modules/programs/anup/settings.nix

@@ -0,0 +1,27 @@
+{
+  programs.anup = {
+    enable = true;
+    config = ''
+      (
+          series_dir: "/home/matteo/anime",
+          reset_dates_on_rewatch: false,
+          episode: (
+              percent_watched_to_progress: (50.0),
+              player: "mpv",
+              player_args: [],
+          ),
+          tui: (
+              keys: (
+                  play_next_episode: "enter",
+              ),
+          ),
+      )
+    '';
+  };
+
+  nmt.script = ''
+    assertFileExists home-files/.config/anup/config.ron
+    assertFileContent home-files/.config/anup/config.ron \
+      ${./config.ron}
+  '';
+}