kraftkit: new module

modules/misc/news/2025/10/2025-10-26_14-36-05.nix

@@ -0,0 +1,10 @@
+{
+  time = "2025-10-26T07:36:05+00:00";
+  condition = true;
+  message = ''
+    A new module is available: `programs.kraftkit`.
+
+    kraftkit is a CLI tool for building custom, minimal, immutable lightweight
+    unikernel virtual machines based on Unikraft.
+  '';
+}

modules/programs/kraftkit.nix

@@ -0,0 +1,50 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+let
+  inherit (lib)
+    mkEnableOption
+    mkPackageOption
+    mkOption
+    mkIf
+    literalExpression
+    ;
+
+  cfg = config.programs.kraftkit;
+  yamlFormat = pkgs.formats.yaml { };
+in
+{
+  meta.maintainers = [ lib.hm.maintainers.folliehiyuki ];
+
+  options.programs.kraftkit = {
+    enable = mkEnableOption "kraftkit - CLI to build and use customized unikernel VMs";
+
+    package = mkPackageOption pkgs "kraft" { nullable = true; };
+
+    settings = mkOption {
+      type = yamlFormat.type;
+      default = { };
+      description = ''
+        Configuration written to {file}`$XDG_CONFIG_HOME/kraftkit/config.yaml`.
+      '';
+      example = literalExpression ''
+        no_prompt = true;
+        log = {
+          level = "info";
+          type = "fancy";
+        };
+      '';
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = mkIf (cfg.package != null) [ cfg.package ];
+
+    xdg.configFile."kraftkit/config.yaml" = mkIf (cfg.settings != { }) {
+      source = yamlFormat.generate "kraftkit-config" cfg.settings;
+    };
+  };
+}

tests/modules/programs/kraftkit/default.nix

@@ -0,0 +1 @@
+{ kraftkit-example-settings = ./example-settings.nix; }

tests/modules/programs/kraftkit/example-config-expected.yaml

@@ -0,0 +1,6 @@
+collect_anonymous_telemetry: false
+log:
+  level: info
+  timestamps: false
+  type: fancy
+no_check_updates: true

tests/modules/programs/kraftkit/example-settings.nix

@@ -0,0 +1,24 @@
+{ config, ... }:
+{
+  programs.kraftkit = {
+    enable = true;
+    package = config.lib.test.mkStubPackage { };
+
+    settings = {
+      no_check_updates = true;
+      collect_anonymous_telemetry = false;
+      log = {
+        level = "info";
+        timestamps = false;
+        type = "fancy";
+      };
+    };
+  };
+
+  nmt.script = ''
+    assertFileExists "home-files/.config/kraftkit/config.yaml"
+    assertFileContent \
+      "home-files/.config/kraftkit/config.yaml" \
+      ${./example-config-expected.yaml}
+  '';
+}