From c6a01e54af81b381695db796a43360bf6db5702f Mon Sep 17 00:00:00 2001
From: Friedrich Altheide <11352905+FriedrichAltheide@users.noreply.github.com>
Date: Thu, 10 Jul 2025 22:36:53 +0200
Subject: [PATCH] docker-cli: add module (#7411)

(cherry picked from commit 729c5e5465a0585b2c492a40d9308ec3ad78a296)
Signed-off-by: Austin Horstman <khaneliman12@gmail.com>
---
 .github/labeler.yml                           |  1 +
 modules/programs/docker-cli.nix               | 65 +++++++++++++++++++
 tests/modules/programs/docker-cli/default.nix |  4 ++
 .../programs/docker-cli/empty-config.nix      | 18 +++++
 .../programs/docker-cli/example-config.json   |  9 +++
 .../programs/docker-cli/example-config.nix    | 37 +++++++++++
 6 files changed, 134 insertions(+)
 create mode 100644 modules/programs/docker-cli.nix
 create mode 100644 tests/modules/programs/docker-cli/default.nix
 create mode 100644 tests/modules/programs/docker-cli/empty-config.nix
 create mode 100644 tests/modules/programs/docker-cli/example-config.json
 create mode 100644 tests/modules/programs/docker-cli/example-config.nix

diff --git a/.github/labeler.yml b/.github/labeler.yml
index f25a8c52d..9791f0be5 100644
--- a/.github/labeler.yml
+++ b/.github/labeler.yml
@@ -163,6 +163,7 @@
       - any-glob-to-any-file:
           - modules/services/podman-linux/**/*
           - modules/programs/distrobox.nix
+          - modules/programs/docker-cli.nix
 "desktop-ui":
   - changed-files:
       - any-glob-to-any-file:
diff --git a/modules/programs/docker-cli.nix b/modules/programs/docker-cli.nix
new file mode 100644
index 000000000..57d91fd58
--- /dev/null
+++ b/modules/programs/docker-cli.nix
@@ -0,0 +1,65 @@
+{
+  lib,
+  pkgs,
+  config,
+  ...
+}:
+let
+  inherit (lib)
+    mkIf
+    mkEnableOption
+    mkOption
+    ;
+
+  cfg = config.programs.docker-cli;
+
+  jsonFormat = pkgs.formats.json { };
+in
+{
+  meta.maintainers = [ lib.maintainers.friedrichaltheide ];
+
+  options.programs.docker-cli = {
+    enable = mkEnableOption "management of docker client config";
+
+    configPath = mkOption {
+      type = lib.types.str;
+      default = ".docker/config.json";
+      description = ''
+        Relative path to the user's home directory where the Docker CLI settings should be stored.
+      '';
+    };
+
+    settings = mkOption {
+      type = jsonFormat.type;
+      default = { };
+      example = ''
+        {
+          "proxies" = {
+            "default" = {
+              "httpProxy" = "http://proxy.example.org:3128";
+              "httpsProxy" = "http://proxy.example.org:3128";
+              "noProxy" = "localhost";
+            };
+          };
+      '';
+      description = ''
+        Available configuration options for the Docker CLI see:
+        <https://docs.docker.com/reference/cli/docker/#docker-cli-configuration-file-configjson-properties
+      '';
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home = {
+      sessionVariables = {
+        DOCKER_CONFIG = "${config.home.homeDirectory}/${cfg.configPath}";
+      };
+
+      file = {
+        "${cfg.configPath}" = {
+          source = jsonFormat.generate "config.json" cfg.settings;
+        };
+      };
+    };
+  };
+}
diff --git a/tests/modules/programs/docker-cli/default.nix b/tests/modules/programs/docker-cli/default.nix
new file mode 100644
index 000000000..e852cf142
--- /dev/null
+++ b/tests/modules/programs/docker-cli/default.nix
@@ -0,0 +1,4 @@
+{
+  docker-cli = ./example-config.nix;
+  docker-cli-empty-config = ./empty-config.nix;
+}
diff --git a/tests/modules/programs/docker-cli/empty-config.nix b/tests/modules/programs/docker-cli/empty-config.nix
new file mode 100644
index 000000000..2cc178741
--- /dev/null
+++ b/tests/modules/programs/docker-cli/empty-config.nix
@@ -0,0 +1,18 @@
+{
+  config,
+  ...
+}:
+let
+  cfgDocker = config.programs.docker-cli;
+in
+{
+  programs.docker-cli = {
+    configPath = ".docker/empty.json";
+  };
+
+  nmt.script = ''
+    assertFileNotRegex home-path/etc/profile.d/hm-session-vars.sh 'DOCKER_CONFIG'
+    assertPathNotExists home-files/.docker/config.json
+    assertPathNotExists home-files/${cfgDocker.configPath}
+  '';
+}
diff --git a/tests/modules/programs/docker-cli/example-config.json b/tests/modules/programs/docker-cli/example-config.json
new file mode 100644
index 000000000..7c642b91d
--- /dev/null
+++ b/tests/modules/programs/docker-cli/example-config.json
@@ -0,0 +1,9 @@
+{
+  "proxies": {
+    "default": {
+      "httpProxy": "http://proxy.example.org:3128",
+      "httpsProxy": "http://proxy.example.org:3128",
+      "noProxy": "localhost"
+    }
+  }
+}
diff --git a/tests/modules/programs/docker-cli/example-config.nix b/tests/modules/programs/docker-cli/example-config.nix
new file mode 100644
index 000000000..576b90f5e
--- /dev/null
+++ b/tests/modules/programs/docker-cli/example-config.nix
@@ -0,0 +1,37 @@
+{
+  config,
+  ...
+}:
+{
+  programs.docker-cli = {
+    enable = true;
+
+    configPath = ".docker/config2.json";
+
+    settings = {
+      "proxies" = {
+        "default" = {
+          "httpProxy" = "http://proxy.example.org:3128";
+          "httpsProxy" = "http://proxy.example.org:3128";
+          "noProxy" = "localhost";
+        };
+      };
+    };
+  };
+
+  nmt.script =
+    let
+      cfgDocker = config.programs.docker-cli;
+      configTestPath = "home-files/${cfgDocker.configPath}";
+      configHomePath = "/home/hm-user/${cfgDocker.configPath}";
+    in
+    ''
+      assertFileContains home-path/etc/profile.d/hm-session-vars.sh \
+        'export DOCKER_CONFIG="${configHomePath}"'
+
+      assertPathNotExists home-files/.docker/config.json
+      assertFileExists ${configTestPath}
+      assertFileContent ${configTestPath} \
+        ${./example-config.json}
+    '';
+}