visidata: add module (#6956)

modules/modules.nix

@@ -295,6 +295,7 @@ let
       ./programs/vinegar.nix
       ./programs/vscode.nix
       ./programs/vscode/haskell.nix
+      ./programs/visidata.nix
       ./programs/pywal.nix
       ./programs/rbenv.nix
       ./programs/wallust.nix

modules/programs/visidata.nix

@@ -0,0 +1,50 @@
+{
+  lib,
+  pkgs,
+  config,
+  ...
+}:
+let
+  inherit (lib)
+    types
+    mkIf
+    mkEnableOption
+    mkPackageOption
+    mkOption
+    ;
+
+  cfg = config.programs.visidata;
+in
+{
+  meta.maintainers = with lib.hm.maintainers; [ aguirre-matteo ];
+
+  options.programs.visidata = {
+    enable = mkEnableOption "Visidata";
+    package = mkPackageOption pkgs "visidata" { nullable = true; };
+    visidatarc = mkOption {
+      type = types.lines;
+      default = "";
+      example = ''
+        options.min_memory_mb=100  # stop processing without 100MB free
+
+        bindkey('0', 'go-leftmost')   # alias '0' to go to first column, like vim
+
+        def median(values):
+            L = sorted(values)
+            return L[len(L)//2]
+
+        vd.aggregator('median', median)
+      '';
+      description = ''
+        Configuration settings and Python function declarations
+        to be written to ~/.visidatarc. All available options
+        can be found here: <https://www.visidata.org/docs/>.
+      '';
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = mkIf (cfg.package != null) [ cfg.package ];
+    home.file.".visidatarc" = mkIf (cfg.visidatarc != "") { text = cfg.visidatarc; };
+  };
+}

tests/default.nix

@@ -309,6 +309,7 @@ import nmtSrc {
       ./modules/programs/uv
       ./modules/programs/vifm
       ./modules/programs/vim-vint
+      ./modules/programs/visidata
       ./modules/programs/vscode
       ./modules/programs/wallust
       ./modules/programs/watson

tests/modules/programs/visidata/config

@@ -0,0 +1,9 @@
+options.min_memory_mb=100
+
+bindkey('0', 'go-leftmost')
+
+def median(values):
+    L = sorted(values)
+    return L[len(L)//2]
+
+vd.aggregator('median', median)

tests/modules/programs/visidata/default.nix

@@ -0,0 +1 @@
+{ visidata-example-config = ./example-config.nix; }

tests/modules/programs/visidata/example-config.nix

@@ -0,0 +1,22 @@
+{
+  programs.visidata = {
+    enable = true;
+    visidatarc = ''
+      options.min_memory_mb=100
+
+      bindkey('0', 'go-leftmost')
+
+      def median(values):
+          L = sorted(values)
+          return L[len(L)//2]
+
+      vd.aggregator('median', median)
+    '';
+  };
+
+  nmt.script = ''
+    assertFileExists home-files/.visidatarc
+    assertFileContent home-files/.visidatarc \
+    ${./config}
+  '';
+}