sketchybar: use finalpackage wrapper

Use finalPackage pattern with wrapper so that people who don't use the
service can benefit from the other options.

Signed-off-by: Austin Horstman <khaneliman12@gmail.com>

modules/misc/news/2025/05/2025-05-22_18-47-11.nix

@@ -0,0 +1,15 @@
+{ pkgs, ... }:
+{
+  time = "2025-05-22T23:47:11+00:00";
+  condition = pkgs.stdenv.hostPlatform.isDarwin;
+  message = ''
+    A new sketchybar module has been added.
+
+    - Simple configuration with a single `config` option that accepts the
+      configuration as lines, a file, or a directory.
+    - Support for both bash and lua configuration types
+    - `extraLuaPackages` option for additional Lua dependencies
+    - `extraPackages` option for additional runtime dependencies
+    - Integrated launchd service management
+  '';
+}

modules/programs/sketchybar.nix

@@ -23,6 +23,13 @@ in
 
     package = lib.mkPackageOption pkgs "sketchybar" { };
 
+    finalPackage = mkOption {
+      type = types.package;
+      readOnly = true;
+      internal = true;
+      description = "Resulting customized sketchybar package.";
+    };
+
     configType = mkOption {
       type = types.enum [
         "bash"
@@ -77,32 +84,16 @@ in
       '';
     };
 
-    service = {
-      enable = mkEnableOption "sketchybar service" // {
-        default = true;
-      };
-
-      errorLogFile = mkOption {
-        type = with lib.types; nullOr (either path str);
-        default = "${config.home.homeDirectory}/Library/Logs/sketchybar/sketchybar.err.log";
-        defaultText = lib.literalExpression "\${config.home.homeDirectory}/Library/Logs/sketchybar/sketchybar.err.log";
-        example = "/Users/khaneliman/Library/Logs/sketchybar.log";
-        description = "Absolute path to log all stderr output.";
-      };
-
-      outLogFile = mkOption {
-        type = with lib.types; nullOr (either path str);
-        default = "${config.home.homeDirectory}/Library/Logs/sketchybar/sketchybar.out.log";
-        defaultText = lib.literalExpression "\${config.home.homeDirectory}/Library/Logs/sketchybar/sketchybar.out.log";
-        example = "/Users/khaneliman/Library/Logs/sketchybar.log";
-        description = "Absolute path to log all stdout output.";
-      };
-
     sbarLuaPackage = lib.mkPackageOption pkgs "sbarlua" {
       nullable = true;
       extraDescription = "Required when using a lua configuration.";
     };
 
+    luaPackage = lib.mkPackageOption pkgs "lua5_4" {
+      nullable = true;
+      extraDescription = "Lua interpreter to use when configType is lua.";
+    };
+
     extraLuaPackages = mkOption {
       type = with types; functionTo (listOf package);
       default = _: [ ];
@@ -124,19 +115,112 @@ in
         Extra packages to add to PATH for the sketchybar service.
       '';
     };
+
+    service = {
+      enable = mkEnableOption "sketchybar service" // {
+        default = true;
+      };
+
+      errorLogFile = mkOption {
+        type = with lib.types; nullOr (either path str);
+        default = "${config.home.homeDirectory}/Library/Logs/sketchybar/sketchybar.err.log";
+        defaultText = lib.literalExpression "\${config.home.homeDirectory}/Library/Logs/sketchybar/sketchybar.err.log";
+        example = "/Users/khaneliman/Library/Logs/sketchybar.log";
+        description = "Absolute path to log all stderr output.";
+      };
+
+      outLogFile = mkOption {
+        type = with lib.types; nullOr (either path str);
+        default = "${config.home.homeDirectory}/Library/Logs/sketchybar/sketchybar.out.log";
+        defaultText = lib.literalExpression "\${config.home.homeDirectory}/Library/Logs/sketchybar/sketchybar.out.log";
+        example = "/Users/khaneliman/Library/Logs/sketchybar.log";
+        description = "Absolute path to log all stdout output.";
+      };
     };
   };
 
-  config = lib.mkMerge [
-    (lib.mkIf cfg.enable {
+  config = lib.mkIf cfg.enable {
     assertions = [
+      (lib.hm.assertions.assertPlatform "programs.sketchybar" pkgs lib.platforms.darwin)
       {
         assertion = !(cfg.configType == "lua" && cfg.sbarLuaPackage == null);
-          message = "When configType is set to \"lua\", sbarLuaPackage must be specified";
+        message = "When configType is set to \"lua\", service.sbarLuaPackage must be specified";
       }
     ];
 
-      home.packages = [ cfg.package ];
+    programs.sketchybar.finalPackage =
+      let
+        resolvedExtraLuaPackages = cfg.extraLuaPackages pkgs.lua54Packages;
+
+        pathPackages =
+          [ cfg.package ]
+          ++ cfg.extraPackages
+          ++ lib.optional (cfg.configType == "lua" && cfg.luaPackage != null) cfg.luaPackage;
+
+        luaPaths = lib.filter (x: x != "") [
+          (lib.optionalString (cfg.configType == "lua" && resolvedExtraLuaPackages != [ ]) (
+            lib.concatMapStringsSep ";" pkgs.lua54Packages.getLuaPath resolvedExtraLuaPackages
+          ))
+          (lib.optionalString (cfg.configType == "lua" && cfg.sbarLuaPackage != null) (
+            pkgs.lua54Packages.getLuaPath cfg.sbarLuaPackage
+          ))
+          (lib.optionalString (cfg.configType == "lua" && cfg.config != null && cfg.config.source != null) (
+            let
+              configDir = "${config.xdg.configHome}/sketchybar";
+            in
+            "${configDir}/?.lua;${configDir}/?/init.lua;${configDir}/?/?.lua"
+          ))
+        ];
+
+        luaCPaths = lib.filter (x: x != "") [
+          (lib.optionalString (cfg.configType == "lua" && resolvedExtraLuaPackages != [ ]) (
+            lib.concatMapStringsSep ";" pkgs.lua54Packages.getLuaCPath resolvedExtraLuaPackages
+          ))
+          (lib.optionalString (cfg.configType == "lua" && cfg.sbarLuaPackage != null) (
+            pkgs.lua54Packages.getLuaCPath cfg.sbarLuaPackage
+          ))
+        ];
+
+        makeWrapperArgs = lib.flatten (
+          lib.filter (x: x != [ ]) [
+            (lib.optional (pathPackages != [ ]) [
+              "--prefix"
+              "PATH"
+              ":"
+              "${lib.makeBinPath pathPackages}"
+            ])
+
+            (lib.optional (luaPaths != [ ]) [
+              "--prefix"
+              "LUA_PATH"
+              ";"
+              "${lib.concatStringsSep ";" luaPaths}"
+            ])
+
+            (lib.optional (luaCPaths != [ ]) [
+              "--prefix"
+              "LUA_CPATH"
+              ";"
+              "${lib.concatStringsSep ";" luaCPaths}"
+            ])
+          ]
+        );
+
+        hasWrapperArgs = makeWrapperArgs != [ ];
+      in
+      if hasWrapperArgs then
+        pkgs.symlinkJoin {
+          name = "sketchybar";
+          paths = [ cfg.package ];
+          nativeBuildInputs = [ pkgs.makeWrapper ];
+          postBuild = ''
+            wrapProgram $out/bin/sketchybar ${lib.escapeShellArgs makeWrapperArgs}
+          '';
+        }
+      else
+        cfg.package;
+
+    home.packages = [ cfg.finalPackage ];
 
     xdg.configFile."sketchybar/sketchybarrc".source = lib.mkIf (cfg.config != "") (
       pkgs.writeTextFile {
@@ -157,39 +241,17 @@ in
         executable = true;
       }
     );
-    })
 
-    (lib.mkIf cfg.service.enable {
-      assertions = [
-        (lib.hm.assertions.assertPlatform "programs.sketchybar" pkgs lib.platforms.darwin)
-      ];
-
-      launchd.agents.sketchybar =
-        let
-          resolvedExtraLuaPackages = cfg.service.extraLuaPackages pkgs.lua54Packages;
-        in
-        {
-          enable = true;
+    launchd.agents.sketchybar = {
+      enable = cfg.service.enable;
       config = {
-            Program = lib.getExe cfg.package;
+        Program = lib.getExe cfg.finalPackage;
         ProcessType = "Interactive";
         KeepAlive = true;
         RunAtLoad = true;
         StandardErrorPath = cfg.service.errorLogFile;
         StandardOutPath = cfg.service.outLogFile;
-            EnvironmentVariables =
-              {
-                PATH = (lib.concatMapStringsSep ":" (p: "${p}/bin") ([ cfg.package ] ++ cfg.service.extraPackages));
-              }
-              // lib.optionalAttrs
-                (cfg.configType == "lua" && (cfg.sbarLuaPackage != null || cfg.extraLuaPackages != (_: [ ])))
-                {
-                  LUA_CPATH = "${
-                    lib.concatMapStringsSep ";" pkgs.lua54Packages.getLuaCPath resolvedExtraLuaPackages
-                  };${cfg.sbarLuaPackage}/lib/lua/${pkgs.lua.luaversion}/?.so";
-                };
-          };
-        };
-    })
-  ];
+      };
+    };
+  };
 }

tests/modules/programs/sketchybar/default.nix

@@ -1,5 +1,4 @@
 {
-  # Combined tests with built-in validation
   sketchybar = ./sketchybar.nix; # Bash configuration with validation
   sketchybar-lua-config = ./sketchybar-lua-config.nix; # Lua configuration with validation
   sketchybar-invalid-lua-config = ./sketchybar-invalid-lua-config.nix; # Tests error on missing sbarLua

tests/modules/programs/sketchybar/sketchybar-invalid-lua-config.nix

@@ -2,22 +2,27 @@
 {
   programs.sketchybar = {
     enable = true;
-    package = config.lib.test.mkStubPackage { };
+    package = config.lib.test.mkStubPackage {
+      name = "sketchybar";
+      buildScript = ''
+        mkdir -p $out/bin
+        touch $out/bin/sketchybar
+        chmod 755 $out/bin/sketchybar
+      '';
+    };
 
     # Test case for lua configuration without sbarLuaPackage
     configType = "lua";
-    # sbarLuaPackage intentionally not set
+    sbarLuaPackage = null;
 
-    variables = {
-      PADDING = 3;
-    };
-
-    config.bar = {
-      height = 30;
-    };
+    config = ''
+      -- Basic lua config
+      local sbar = require("sbarlua")
+      sbar.bar:set({ height = 30 })
+    '';
   };
 
   test.asserts.assertions.expected = [
-    "When configType is set to \"lua\", sbarLuaPackage must be specified"
+    "When configType is set to \"lua\", service.sbarLuaPackage must be specified"
   ];
 }

tests/modules/programs/sketchybar/sketchybar-lua-config.nix

@@ -14,58 +14,54 @@ in
 {
   programs.sketchybar = {
     enable = true;
-    package = config.lib.test.mkStubPackage { };
+    package = config.lib.test.mkStubPackage {
+      name = "sketchybar";
+      buildScript = ''
+        mkdir -p $out/bin
+        touch $out/bin/sketchybar
+        chmod 755 $out/bin/sketchybar
+      '';
+    };
 
     configType = "lua";
+
     sbarLuaPackage = pkgsSbarlua;
 
-    variables = {
-      PADDING = 3;
-      FONT = "SF Pro";
-      COLOR = "0xff0000ff";
-      # Test more complex values
-      ITEMS = [
-        "calendar"
-        "cpu"
-        "memory"
-      ];
-      SETTINGS = {
-        refresh_freq = 1;
-        enable_logging = true;
-      };
-    };
-
-    config = {
-      bar = {
-        height = 30;
-        position = "top";
-        padding_left = 10;
-        padding_right = 10;
-        blur_radius = 20;
-        corner_radius = 9;
-      };
-
-      defaults = {
-        "icon.font" = "$FONT";
-        "icon.color" = "$COLOR";
-        "background.height" = 24;
-        "label.padding" = "$PADDING";
-        "popup.background.border_width" = 2;
-        "popup.background.corner_radius" = 9;
-      };
-    };
-
-    extraConfig = ''
+    config = ''
       -- This is a test Lua configuration
+      local sbar = require("sbarlua")
+
+      -- Configure bar
+      sbar.bar:set({
+        height = 30,
+        position = "top",
+        padding_left = 10,
+        padding_right = 10,
+        blur_radius = 20,
+        corner_radius = 9,
+      })
+
+      -- Configure defaults
+      sbar.defaults:set({
+        ["icon.font"] = "SF Pro",
+        ["icon.color"] = "0xff0000ff",
+        ["background.height"] = 24,
+        ["popup.background.border_width"] = 2,
+        ["popup.background.corner_radius"] = 9,
+      })
+
+      -- Add items
       sbar:add("item", "cpu", {
         position = "right",
         update_freq = 1,
-        script = "./scripts/cpu.lua"
+        script = "./scripts/cpu.lua",
       })
 
       -- Subscribe to events
       sbar:subscribe("cpu", "system_woke")
-    '';
+
+      -- Update the bar
+      sbar:update()'';
   };
 
   # Validate the generated Lua configuration file

tests/modules/programs/sketchybar/sketchybar-service-expected.plist

@@ -2,11 +2,6 @@
 <!DOCTYPE plist PUBLIC "-//Apple Computer//DTD PLIST 1.0//EN" "http://www.apple.com/DTDs/PropertyList-1.0.dtd">
 <plist version="1.0">
 <dict>
-	<key>EnvironmentVariables</key>
-	<dict>
-		<key>PATH</key>
-		<string>/@sketchybar@/bin:/@jq@/bin</string>
-	</dict>
 	<key>KeepAlive</key>
 	<true/>
 	<key>Label</key>

tests/modules/programs/sketchybar/sketchybar-service-integration.nix

@@ -9,7 +9,11 @@ let
     self: super: {
       sketchybar = config.lib.test.mkStubPackage {
         name = "sketchybar";
-        outPath = "/@sketchybar@";
+        buildScript = ''
+          mkdir -p $out/bin
+          touch $out/bin/sketchybar
+          chmod 755 $out/bin/sketchybar
+        '';
       };
       jq = config.lib.test.mkStubPackage { outPath = "/@jq@"; };
     }
@@ -21,23 +25,22 @@ in
     package = hmPkgs.sketchybar;
     configType = "bash";
 
-    variables = {
-      PADDING = "3";
-      FONT = "SF Pro";
-      COLOR = "0xff0000ff";
-    };
+    config = ''
+      #!/usr/bin/env bash
 
-    config.bar = {
-      height = 30;
-      position = "top";
-      padding_left = 10;
-      padding_right = 10;
-    };
+      # Configure bar
+      sketchybar --bar height=30 \
+                      position=top \
+                      padding_left=10 \
+                      padding_right=10
+
+      # Update the bar
+      sketchybar --update
+    '';
 
     # Enable the integrated service
     service = {
       enable = true;
-      extraPackages = [ hmPkgs.jq ];
       errorLogFile = "/home/hm-user/Library/Logs/sketchybar/sketchybar.err.log";
       outLogFile = "/home/hm-user/Library/Logs/sketchybar/sketchybar.out.log";
     };

tests/modules/programs/sketchybar/sketchybar.nix

@@ -3,45 +3,42 @@
 {
   programs.sketchybar = {
     enable = true;
-    package = config.lib.test.mkStubPackage { };
+    package = config.lib.test.mkStubPackage {
+      name = "sketchybar";
+      buildScript = ''
+        mkdir -p $out/bin
+        touch $out/bin/sketchybar
+        chmod 755 $out/bin/sketchybar
+      '';
+    };
 
     configType = "bash";
 
-    variables = {
-      PADDING = "3";
-      FONT = "SF Pro";
-      COLOR = "0xff0000ff";
-    };
+    config = ''
+      # Define colors
+      export COLOR_BLACK="0xff181926"
+      export COLOR_WHITE="0xffcad3f5"
 
-    config = {
-      bar = {
-        height = 30;
-        position = "top";
-        padding_left = 10;
-        padding_right = 10;
-      };
+      # Configure bar
+      sketchybar --bar height=32 \
+                      position=top \
+                      padding_left=10 \
+                      padding_right=10 \
+                      color=$COLOR_BLACK
 
-      defaults = {
-        "icon.font" = "$FONT";
-        "icon.color" = "$COLOR";
-        "background.height" = 24;
-      };
-    };
+      # Configure default values
+      sketchybar --default icon.font="SF Pro:Bold:14.0" \
+                          icon.color=$COLOR_WHITE \
+                          label.font="SF Pro:Bold:14.0" \
+                          label.color=$COLOR_WHITE
 
-    plugins = [
-      {
-        name = "clock";
-        placement = "right";
-        script = "./scripts/clock.sh";
-        update_freq = 1;
-      }
-    ];
+      # Add items to the bar
+      sketchybar --add item clock right \
+                --set clock script="date '+%H:%M'" \
+                            update_freq=10
 
-    extraConfig = ''
-      # This is a test configuration
-      sketchybar --add item cpu right \
-                --set cpu script="$PLUGIN_DIR/cpu.sh" \
-                --subscribe cpu system_woke
+      # Update the bar
+      sketchybar --update
     '';
   };
 

tests/modules/programs/sketchybar/sketchybarrc.bash

@@ -1,26 +1,27 @@
-export COLOR=0xff0000ff
-export FONT=SF Pro
-export PADDING=3
+#!/usr/bin/env bash
+# Generated by home-manager
+# Define colors
+export COLOR_BLACK="0xff181926"
+export COLOR_WHITE="0xffcad3f5"
 
-sketchybar --bar \
-height=30 \
+# Configure bar
+sketchybar --bar height=32 \
+                position=top \
                 padding_left=10 \
                 padding_right=10 \
-position=top
+                color=$COLOR_BLACK
 
-sketchybar --default \
-background.height=24 \
-icon.color=$COLOR \
-icon.font=$FONT
-
-
-sketchybar --add item clock right --set clock script=./scripts/clock.sh update_freq=1
-
-
-# This is a test configuration
-sketchybar --add item cpu right \
-          --set cpu script="$PLUGIN_DIR/cpu.sh" \
-          --subscribe cpu system_woke
+# Configure default values
+sketchybar --default icon.font="SF Pro:Bold:14.0" \
+                    icon.color=$COLOR_WHITE \
+                    label.font="SF Pro:Bold:14.0" \
+                    label.color=$COLOR_WHITE
 
+# Add items to the bar
+sketchybar --add item clock right \
+          --set clock script="date '+%H:%M'" \
+                      update_freq=10
 
+# Update the bar
 sketchybar --update
+

tests/modules/programs/sketchybar/sketchybarrc.lua

@@ -1,52 +1,36 @@
 #!/usr/bin/env lua
 -- Generated by home-manager
+-- This is a test Lua configuration
 local sbar = require("sbarlua")
 
--- Set variables
-sbar.variables["COLOR"] = "0xff0000ff"
-sbar.variables["FONT"] = "SF Pro"
-sbar.variables["ITEMS"] = {
-  "calendar",
-  "cpu",
-  "memory"
-}
-sbar.variables["PADDING"] = 3
-sbar.variables["SETTINGS"] = {
-  ["enable_logging"] = true,
-  ["refresh_freq"] = 1
-}
-
 -- Configure bar
 sbar.bar:set({
-  ["blur_radius"] = 20,
-  ["corner_radius"] = 9,
-  ["height"] = 30,
-  ["padding_left"] = 10,
-  ["padding_right"] = 10,
-  ["position"] = "top"
+  height = 30,
+  position = "top",
+  padding_left = 10,
+  padding_right = 10,
+  blur_radius = 20,
+  corner_radius = 9,
 })
 
 -- Configure defaults
 sbar.defaults:set({
+  ["icon.font"] = "SF Pro",
+  ["icon.color"] = "0xff0000ff",
   ["background.height"] = 24,
-  ["icon.color"] = "$COLOR",
-  ["icon.font"] = "$FONT",
-  ["label.padding"] = "$PADDING",
   ["popup.background.border_width"] = 2,
-  ["popup.background.corner_radius"] = 9
+  ["popup.background.corner_radius"] = 9,
 })
 
--- Extra configuration
--- This is a test Lua configuration
+-- Add items
 sbar:add("item", "cpu", {
   position = "right",
   update_freq = 1,
-  script = "./scripts/cpu.lua"
+  script = "./scripts/cpu.lua",
 })
 
 -- Subscribe to events
 sbar:subscribe("cpu", "system_woke")
 
-
 -- Update the bar
 sbar:update()