mirror of
https://github.com/nix-community/home-manager.git
synced 2025-11-08 19:46:05 +01:00
4fca600cb1
Reduce maintenance burden and increase efficiency by automatically importing modules following a specific convention. Co-authored-by: awwpotato <awwpotato@voidq.com> Signed-off-by: Austin Horstman <khaneliman12@gmail.com>
58 lines
1.4 KiB
Nix
58 lines
1.4 KiB
Nix
# Adapted from Nixpkgs.
|
|
|
|
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
let
|
|
cfg = config.programs.command-not-found;
|
|
cnfScript = pkgs.replaceVars ./command-not-found.pl {
|
|
inherit (cfg) dbPath;
|
|
perl = pkgs.perl.withPackages (p: [
|
|
p.DBDSQLite
|
|
p.StringShellQuote
|
|
]);
|
|
};
|
|
commandNotFound = pkgs.runCommand "command-not-found" { } ''
|
|
install -Dm555 ${cnfScript} $out/bin/command-not-found
|
|
'';
|
|
|
|
shInit = commandNotFoundHandlerName: ''
|
|
# This function is called whenever a command is not found.
|
|
${commandNotFoundHandlerName}() {
|
|
local p=${commandNotFound}/bin/command-not-found
|
|
if [ -x $p -a -f ${cfg.dbPath} ]; then
|
|
# Run the helper program.
|
|
$p "$@"
|
|
else
|
|
echo "$1: command not found" >&2
|
|
return 127
|
|
fi
|
|
}
|
|
'';
|
|
|
|
in
|
|
{
|
|
options.programs.command-not-found = {
|
|
enable = lib.mkEnableOption "command-not-found hook for interactive shell";
|
|
|
|
dbPath = lib.mkOption {
|
|
default = "/nix/var/nix/profiles/per-user/root/channels/nixos/programs.sqlite";
|
|
description = ''
|
|
Absolute path to {file}`programs.sqlite`. By
|
|
default this file will be provided by your channel
|
|
(nixexprs.tar.xz).
|
|
'';
|
|
type = lib.types.path;
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
programs.bash.initExtra = shInit "command_not_found_handle";
|
|
programs.zsh.initContent = shInit "command_not_found_handler";
|
|
|
|
home.packages = [ commandNotFound ];
|
|
};
|
|
}
|