mirror of
https://github.com/nix-community/home-manager.git
synced 2025-11-08 11:36:05 +01:00
7419250703
This commit converts `package = mkOption` declarations throughout the
codebase to use the more modern and consistent `lib.mkPackageOption`
function.
Key changes:
- Simple package options: `mkOption { type = types.package; default = pkgs.foo; }`
becomes `lib.mkPackageOption pkgs "foo" { }`
- Package set options: Uses correct package set as first argument with
`pkgsText` parameter (e.g., `lib.mkPackageOption pkgs.vimPlugins "plugin" { pkgsText = "pkgs.vimPlugins"; }`)
- Removes redundant descriptions that just restate the package name
- Preserves examples and extra context where meaningful
- Handles submodule plugin options properly with `null` defaults
This modernizes the option declarations and makes them more consistent
with current nixpkgs patterns while maintaining full backward compatibility.
Signed-off-by: Austin Horstman <khaneliman12@gmail.com>
72 lines
1.5 KiB
Nix
72 lines
1.5 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
let
|
|
inherit (lib) mkOption types;
|
|
|
|
cfg = config.services.etesync-dav;
|
|
|
|
toEnvironmentCfg =
|
|
vars: (lib.concatStringsSep " " (lib.mapAttrsToList (k: v: "${k}=${lib.escapeShellArg v}") vars));
|
|
|
|
in
|
|
{
|
|
meta.maintainers = [ lib.maintainers.valodim ];
|
|
|
|
options.services.etesync-dav = {
|
|
enable = lib.mkEnableOption "etesync-dav";
|
|
|
|
package = lib.mkPackageOption pkgs "etesync-dav" { };
|
|
|
|
serverUrl = mkOption {
|
|
type = types.str;
|
|
default = "https://api.etebase.com/partner/etesync/";
|
|
description = "The URL to the etesync server.";
|
|
};
|
|
|
|
settings = mkOption {
|
|
type = types.attrsOf (
|
|
types.oneOf [
|
|
types.str
|
|
types.int
|
|
]
|
|
);
|
|
default = { };
|
|
example = lib.literalExpression ''
|
|
{
|
|
ETESYNC_LISTEN_ADDRESS = "localhost";
|
|
ETESYNC_LISTEN_PORT = 37358;
|
|
}
|
|
'';
|
|
description = ''
|
|
Settings for etesync-dav, passed as environment variables.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
assertions = [
|
|
(lib.hm.assertions.assertPlatform "services.etesync-dav" pkgs lib.platforms.linux)
|
|
];
|
|
|
|
home.packages = [ cfg.package ];
|
|
|
|
systemd.user.services.etesync-dav = {
|
|
Unit = {
|
|
Description = "etesync-dav";
|
|
};
|
|
|
|
Service = {
|
|
ExecStart = "${cfg.package}/bin/etesync-dav";
|
|
Environment = toEnvironmentCfg ({ ETESYNC_URL = cfg.serverUrl; } // cfg.settings);
|
|
};
|
|
|
|
Install = {
|
|
WantedBy = [ "default.target" ];
|
|
};
|
|
};
|
|
};
|
|
}
|