mirror of
https://github.com/nix-community/home-manager.git
synced 2025-11-08 11:36:05 +01:00
7419250703
This commit converts `package = mkOption` declarations throughout the
codebase to use the more modern and consistent `lib.mkPackageOption`
function.
Key changes:
- Simple package options: `mkOption { type = types.package; default = pkgs.foo; }`
becomes `lib.mkPackageOption pkgs "foo" { }`
- Package set options: Uses correct package set as first argument with
`pkgsText` parameter (e.g., `lib.mkPackageOption pkgs.vimPlugins "plugin" { pkgsText = "pkgs.vimPlugins"; }`)
- Removes redundant descriptions that just restate the package name
- Preserves examples and extra context where meaningful
- Handles submodule plugin options properly with `null` defaults
This modernizes the option declarations and makes them more consistent
with current nixpkgs patterns while maintaining full backward compatibility.
Signed-off-by: Austin Horstman <khaneliman12@gmail.com>
60 lines
1.5 KiB
Nix
60 lines
1.5 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
let
|
|
inherit (lib) mkOption types;
|
|
|
|
cfg = config.xsession.windowManager.awesome;
|
|
awesome = cfg.package;
|
|
getLuaPath = lib: dir: "${lib}/${dir}/lua/${awesome.lua.luaversion}";
|
|
makeSearchPath = lib.concatMapStrings (
|
|
path: " --search ${getLuaPath path "share"}" + " --search ${getLuaPath path "lib"}"
|
|
);
|
|
|
|
in
|
|
{
|
|
options = {
|
|
xsession.windowManager.awesome = {
|
|
enable = lib.mkEnableOption "Awesome window manager";
|
|
|
|
package = lib.mkPackageOption pkgs "awesome" {
|
|
extraDescription = "to use for running the Awesome WM";
|
|
};
|
|
|
|
luaModules = mkOption {
|
|
default = [ ];
|
|
type = types.listOf types.package;
|
|
description = ''
|
|
List of lua packages available for being
|
|
used in the Awesome configuration.
|
|
'';
|
|
example = lib.literalExpression "[ pkgs.luaPackages.vicious ]";
|
|
};
|
|
|
|
noArgb = mkOption {
|
|
default = false;
|
|
type = types.bool;
|
|
description = ''
|
|
Disable client transparency support, which can be greatly
|
|
detrimental to performance in some setups
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
assertions = [
|
|
(lib.hm.assertions.assertPlatform "xsession.windowManager.awesome" pkgs lib.platforms.linux)
|
|
];
|
|
|
|
home.packages = [ awesome ];
|
|
|
|
xsession.windowManager.command =
|
|
"${awesome}/bin/awesome "
|
|
+ lib.optionalString cfg.noArgb "--no-argb "
|
|
+ makeSearchPath cfg.luaModules;
|
|
};
|
|
}
|