mirror of
https://github.com/nix-community/home-manager.git
synced 2025-11-08 11:36:05 +01:00
7419250703
This commit converts `package = mkOption` declarations throughout the
codebase to use the more modern and consistent `lib.mkPackageOption`
function.
Key changes:
- Simple package options: `mkOption { type = types.package; default = pkgs.foo; }`
becomes `lib.mkPackageOption pkgs "foo" { }`
- Package set options: Uses correct package set as first argument with
`pkgsText` parameter (e.g., `lib.mkPackageOption pkgs.vimPlugins "plugin" { pkgsText = "pkgs.vimPlugins"; }`)
- Removes redundant descriptions that just restate the package name
- Preserves examples and extra context where meaningful
- Handles submodule plugin options properly with `null` defaults
This modernizes the option declarations and makes them more consistent
with current nixpkgs patterns while maintaining full backward compatibility.
Signed-off-by: Austin Horstman <khaneliman12@gmail.com>
67 lines
1.6 KiB
Nix
67 lines
1.6 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
|
|
let
|
|
|
|
cfg = config.services.xscreensaver;
|
|
|
|
in
|
|
{
|
|
meta.maintainers = [ lib.maintainers.rycee ];
|
|
|
|
options = {
|
|
services.xscreensaver = {
|
|
enable = lib.mkEnableOption "XScreenSaver";
|
|
|
|
settings = lib.mkOption {
|
|
type = with lib.types; attrsOf (either bool (either int str));
|
|
default = { };
|
|
example = {
|
|
mode = "blank";
|
|
lock = false;
|
|
fadeTicks = 20;
|
|
};
|
|
description = ''
|
|
The settings to use for XScreenSaver.
|
|
'';
|
|
};
|
|
|
|
package = lib.mkPackageOption pkgs "xscreensaver" { };
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
assertions = [
|
|
(lib.hm.assertions.assertPlatform "services.xscreensaver" pkgs lib.platforms.linux)
|
|
];
|
|
|
|
# To make the lib.xscreensaver-command tool available.
|
|
home.packages = [ cfg.package ];
|
|
|
|
xresources.properties = lib.mapAttrs' (n: lib.nameValuePair "xscreensaver.${n}") cfg.settings;
|
|
|
|
systemd.user.services.xscreensaver = {
|
|
Unit = {
|
|
Description = "XScreenSaver";
|
|
After = [ "graphical-session.target" ];
|
|
PartOf = [ "graphical-session.target" ];
|
|
|
|
# Make sure the service is restarted if the settings change.
|
|
X-Restart-Triggers = [ (builtins.hashString "md5" (builtins.toJSON cfg.settings)) ];
|
|
};
|
|
|
|
Service = {
|
|
ExecStart = "${cfg.package}/bin/xscreensaver -no-splash";
|
|
Environment = [ "PATH=${lib.makeBinPath [ cfg.package ]}" ];
|
|
};
|
|
|
|
Install = {
|
|
WantedBy = [ "graphical-session.target" ];
|
|
};
|
|
};
|
|
};
|
|
}
|