mirror of
https://github.com/nix-community/home-manager.git
synced 2025-12-06 09:01:04 +01:00
7419250703
This commit converts `package = mkOption` declarations throughout the
codebase to use the more modern and consistent `lib.mkPackageOption`
function.
Key changes:
- Simple package options: `mkOption { type = types.package; default = pkgs.foo; }`
becomes `lib.mkPackageOption pkgs "foo" { }`
- Package set options: Uses correct package set as first argument with
`pkgsText` parameter (e.g., `lib.mkPackageOption pkgs.vimPlugins "plugin" { pkgsText = "pkgs.vimPlugins"; }`)
- Removes redundant descriptions that just restate the package name
- Preserves examples and extra context where meaningful
- Handles submodule plugin options properly with `null` defaults
This modernizes the option declarations and makes them more consistent
with current nixpkgs patterns while maintaining full backward compatibility.
Signed-off-by: Austin Horstman <khaneliman12@gmail.com>
67 lines
1.4 KiB
Nix
67 lines
1.4 KiB
Nix
{
|
|
config,
|
|
lib,
|
|
pkgs,
|
|
...
|
|
}:
|
|
|
|
let
|
|
inherit (lib) literalExpression;
|
|
|
|
cfg = config.services.spotifyd;
|
|
|
|
tomlFormat = pkgs.formats.toml { };
|
|
|
|
configFile = tomlFormat.generate "spotifyd.conf" cfg.settings;
|
|
|
|
in
|
|
{
|
|
options.services.spotifyd = {
|
|
enable = lib.mkEnableOption "SpotifyD connect";
|
|
|
|
package = lib.mkPackageOption pkgs "spotifyd" {
|
|
example = "(pkgs.spotifyd.override { withKeyring = true; })";
|
|
extraDescription = ''
|
|
Can be used to specify extensions.
|
|
'';
|
|
};
|
|
|
|
settings = lib.mkOption {
|
|
type = tomlFormat.type;
|
|
default = { };
|
|
description = "Configuration for spotifyd";
|
|
example = literalExpression ''
|
|
{
|
|
global = {
|
|
username = "Alex";
|
|
password = "foo";
|
|
device_name = "nix";
|
|
};
|
|
}
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
assertions = [
|
|
(lib.hm.assertions.assertPlatform "services.spotifyd" pkgs lib.platforms.linux)
|
|
];
|
|
|
|
home.packages = [ cfg.package ];
|
|
|
|
systemd.user.services.spotifyd = {
|
|
Unit = {
|
|
Description = "spotify daemon";
|
|
Documentation = "https://github.com/Spotifyd/spotifyd";
|
|
};
|
|
|
|
Install.WantedBy = [ "default.target" ];
|
|
|
|
Service = {
|
|
ExecStart = "${cfg.package}/bin/spotifyd --no-daemon --config-path ${configFile}";
|
|
Restart = "always";
|
|
RestartSec = 12;
|
|
};
|
|
};
|
|
};
|
|
}
|