mirror of
https://github.com/nix-community/nix-on-droid.git
synced 2025-11-08 19:46:07 +01:00
37 lines
1.2 KiB
Nix
37 lines
1.2 KiB
Nix
# Copyright (c) 2019-2020, see AUTHORS. Licensed under MIT License, see LICENSE.
|
|
|
|
{ pkgs ? import <nixpkgs> { }, home-manager ? import <home-manager> { }, config ? null, isFlake ? false }:
|
|
|
|
with pkgs.lib;
|
|
|
|
let
|
|
defaultConfigFile = "${builtins.getEnv "HOME"}/.config/nixpkgs/nix-on-droid.nix";
|
|
|
|
configModule =
|
|
if config != null then config
|
|
else if builtins.pathExists defaultConfigFile then defaultConfigFile
|
|
else if pkgs.config ? nix-on-droid then pkgs.config.nix-on-droid
|
|
else throw "No config file found! Create one in ~/.config/nixpkgs/nix-on-droid.nix";
|
|
|
|
rawModule = evalModules {
|
|
modules = [
|
|
{
|
|
_module.args.home-manager = home-manager;
|
|
_module.args.pkgs = mkDefault pkgs;
|
|
}
|
|
configModule
|
|
] ++ import ./module-list.nix { inherit pkgs isFlake; };
|
|
};
|
|
|
|
failedAssertions = map (x: x.message) (filter (x: !x.assertion) rawModule.config.assertions);
|
|
|
|
module =
|
|
if failedAssertions != []
|
|
then throw "\nFailed assertions:\n${concatMapStringsSep "\n" (x: "- ${x}") failedAssertions}"
|
|
else showWarnings rawModule.config.warnings rawModule;
|
|
in
|
|
|
|
{
|
|
inherit (module.config.build) activationPackage;
|
|
inherit (module) config;
|
|
}
|