mirror of
https://github.com/NixOS/nix.git
synced 2025-12-16 05:51:05 +01:00
0feeab755a
They are not actually part of the store layer, but instead part of the Nix executable infra (libraries don't need plugins, executables do). This is part of a larger project of moving all of our legacy settings infra to libmain, and having the underlying libraries just have plain configuration structs detached from any settings infra / UI layer. Progress on #5638
84 lines
1.9 KiB
Meson
84 lines
1.9 KiB
Meson
project('nix-main-c', 'cpp',
|
|
version : files('.version'),
|
|
default_options : [
|
|
'cpp_std=c++2a',
|
|
# TODO(Qyriad): increase the warning level
|
|
'warning_level=1',
|
|
'debug=true',
|
|
'optimization=2',
|
|
'errorlogs=true', # Please print logs for tests that fail
|
|
],
|
|
meson_version : '>= 1.1',
|
|
license : 'LGPL-2.1-or-later',
|
|
)
|
|
|
|
cxx = meson.get_compiler('cpp')
|
|
|
|
subdir('build-utils-meson/deps-lists')
|
|
|
|
configdata = configuration_data()
|
|
|
|
deps_private_maybe_subproject = [
|
|
dependency('nix-util'),
|
|
dependency('nix-store'),
|
|
dependency('nix-main'),
|
|
]
|
|
deps_public_maybe_subproject = [
|
|
dependency('nix-util-c'),
|
|
dependency('nix-store-c'),
|
|
]
|
|
subdir('build-utils-meson/subprojects')
|
|
|
|
# TODO rename, because it will conflict with downstream projects
|
|
configdata.set_quoted('PACKAGE_VERSION', meson.project_version())
|
|
|
|
config_h = configure_file(
|
|
configuration : configdata,
|
|
output : 'config-main.h',
|
|
)
|
|
|
|
add_project_arguments(
|
|
# TODO(Qyriad): Yes this is how the autoconf+Make system did it.
|
|
# It would be nice for our headers to be idempotent instead.
|
|
|
|
# From C++ libraries, only for internals
|
|
'-include', 'config-util.hh',
|
|
'-include', 'config-store.hh',
|
|
'-include', 'config-main.hh',
|
|
|
|
# From C libraries, for our public, installed headers too
|
|
'-include', 'config-util.h',
|
|
'-include', 'config-store.h',
|
|
'-include', 'config-main.h',
|
|
language : 'cpp',
|
|
)
|
|
|
|
subdir('build-utils-meson/diagnostics')
|
|
|
|
sources = files(
|
|
'nix_api_main.cc',
|
|
)
|
|
|
|
include_dirs = [include_directories('.')]
|
|
|
|
headers = [config_h] + files(
|
|
'nix_api_main.h',
|
|
)
|
|
|
|
subdir('build-utils-meson/export-all-symbols')
|
|
|
|
this_library = library(
|
|
'nixmainc',
|
|
sources,
|
|
dependencies : deps_public + deps_private + deps_other,
|
|
include_directories : include_dirs,
|
|
link_args: linker_export_flags,
|
|
prelink : true, # For C++ static initializers
|
|
install : true,
|
|
)
|
|
|
|
install_headers(headers, subdir : 'nix', preserve_path : true)
|
|
|
|
libraries_private = []
|
|
|
|
subdir('build-utils-meson/export')
|