Add hydra jobs & flake packages

microsoft/surface/common/default.nix

@@ -10,85 +10,10 @@ let
     mkDefault
     mkOption
     types
-    versions
     ;
 
-  # Set the version and hash for the kernel sources
-  srcVersion =
-    with config.hardware.microsoft-surface;
-    if kernelVersion == "longterm" then
-      "6.12.19"
-    else if kernelVersion == "stable" then
-      "6.15.9"
-    else
-      abort "Invalid kernel version: ${kernelVersion}";
-
-  srcHash =
-    with config.hardware.microsoft-surface;
-    if kernelVersion == "longterm" then
-      "sha256-1zvwV77ARDSxadG2FkGTb30Ml865I6KB8y413U3MZTE="
-    else if kernelVersion == "stable" then
-      "sha256-6U86+FSSMC96gZRBRY+AvKCtmRLlpMg8aZ/zxjxSlX0="
-    else
-      abort "Invalid kernel version: ${kernelVersion}";
-
-  # Set the version and hash for the linux-surface releases
-  pkgVersion =
-    with config.hardware.microsoft-surface;
-    if kernelVersion == "longterm" then
-      "6.12.7"
-    else if kernelVersion == "stable" then
-      "6.15.3"
-    else
-      abort "Invalid kernel version: ${kernelVersion}";
-
-  pkgHash =
-    with config.hardware.microsoft-surface;
-    if kernelVersion == "longterm" then
-      "sha256-Pv7O8D8ma+MPLhYP3HSGQki+Yczp8b7d63qMb6l4+mY="
-    else if kernelVersion == "stable" then
-      "sha256-ozvYrZDiVtMkdCcVnNEdlF2Kdw4jivW0aMJrDynN3Hk="
-    else
-      abort "Invalid kernel version: ${kernelVersion}";
-
-  # Fetch the linux-surface package
-  repos =
-    pkgs.callPackage
-      (
-        {
-          fetchFromGitHub,
-          rev,
-          hash,
-        }:
-        {
-          linux-surface = fetchFromGitHub {
-            owner = "linux-surface";
-            repo = "linux-surface";
-            rev = rev;
-            hash = hash;
-          };
-        }
-      )
-      {
-        hash = pkgHash;
-        rev = "arch-${pkgVersion}-1";
-      };
-
-  # Fetch and build the kernel package
-  inherit (pkgs.callPackage ./kernel/linux-package.nix { inherit repos; })
-    linuxPackage
-    surfacePatches
-    ;
-  kernelPatches = surfacePatches {
-    version = pkgVersion;
-    patchFn = ./kernel/${versions.majorMinor pkgVersion}/patches.nix;
-    patchSrc = (repos.linux-surface + "/patches/${versions.majorMinor pkgVersion}");
-  };
-  kernelPackages = linuxPackage {
-    inherit kernelPatches;
-    version = srcVersion;
-    sha256 = srcHash;
-    ignoreConfigErrors = true;
+  kernelPackages = pkgs.callPackage ../pkgs/kernel {
+    inherit (config.hardware.microsoft-surface) kernelVersion;
   };
 
 in

microsoft/surface/pkgs/all.nix

@@ -0,0 +1,12 @@
+{
+  lib,
+  stdenv,
+  callPackages,
+}:
+let
+  pkgs = callPackages ./. { };
+in
+lib.optionalAttrs (stdenv.hostPlatform.isx86_64) {
+  kernel-stable = pkgs.kernel-stable.kernel;
+  kernel-longterm = pkgs.kernel-longterm.kernel;
+}

microsoft/surface/pkgs/default.nix

@@ -0,0 +1,10 @@
+{ callPackage }:
+{
+  kernel-stable = callPackage ./kernel {
+    kernelVersion = "stable";
+  };
+
+  kernel-longterm = callPackage ./kernel {
+    kernelVersion = "longterm";
+  };
+}

microsoft/surface/pkgs/jobs.nix

@@ -0,0 +1,8 @@
+nixpkgs:
+let
+  pkgs = nixpkgs.legacyPackages.x86_64-linux.callPackages ./. { };
+in
+{
+  kernel-stable.x86_64-linux = nixpkgs.lib.hydraJob pkgs.kernel-stable.kernel;
+  kernel-longterm.x86_64-linux = nixpkgs.lib.hydraJob pkgs.kernel-longterm.kernel;
+}

microsoft/surface/pkgs/kernel/default.nix

@@ -0,0 +1,83 @@
+{
+  lib,
+  kernelVersion,
+  callPackage,
+}:
+let
+  inherit (lib) versions;
+
+  # Set the version and hash for the kernel sources
+  srcVersion =
+    if kernelVersion == "longterm" then
+      "6.12.19"
+    else if kernelVersion == "stable" then
+      "6.15.9"
+    else
+      abort "Invalid kernel version: ${kernelVersion}";
+
+  srcHash =
+    if kernelVersion == "longterm" then
+      "sha256-1zvwV77ARDSxadG2FkGTb30Ml865I6KB8y413U3MZTE="
+    else if kernelVersion == "stable" then
+      "sha256-6U86+FSSMC96gZRBRY+AvKCtmRLlpMg8aZ/zxjxSlX0="
+    else
+      abort "Invalid kernel version: ${kernelVersion}";
+
+  # Set the version and hash for the linux-surface releases
+  pkgVersion =
+    if kernelVersion == "longterm" then
+      "6.12.7"
+    else if kernelVersion == "stable" then
+      "6.15.3"
+    else
+      abort "Invalid kernel version: ${kernelVersion}";
+
+  pkgHash =
+    if kernelVersion == "longterm" then
+      "sha256-Pv7O8D8ma+MPLhYP3HSGQki+Yczp8b7d63qMb6l4+mY="
+    else if kernelVersion == "stable" then
+      "sha256-ozvYrZDiVtMkdCcVnNEdlF2Kdw4jivW0aMJrDynN3Hk="
+    else
+      abort "Invalid kernel version: ${kernelVersion}";
+
+  # Fetch the linux-surface package
+  repos =
+    callPackage
+      (
+        {
+          fetchFromGitHub,
+          rev,
+          hash,
+        }:
+        {
+          linux-surface = fetchFromGitHub {
+            owner = "linux-surface";
+            repo = "linux-surface";
+            rev = rev;
+            hash = hash;
+          };
+        }
+      )
+      {
+        hash = pkgHash;
+        rev = "arch-${pkgVersion}-1";
+      };
+
+  # Fetch and build the kernel package
+  inherit (callPackage ../../common/kernel/linux-package.nix { inherit repos; })
+    linuxPackage
+    surfacePatches
+    ;
+
+  kernelPatches = surfacePatches {
+    version = pkgVersion;
+    patchFn = ../../common/kernel/${versions.majorMinor pkgVersion}/patches.nix;
+    patchSrc = (repos.linux-surface + "/patches/${versions.majorMinor pkgVersion}");
+  };
+in
+linuxPackage {
+  inherit kernelPatches;
+  version = srcVersion;
+  sha256 = srcHash;
+  ignoreConfigErrors = true;
+}